Der ESP8266 lässt sich einfach mit der passenden Bibliothek als Infrarot-Fernbedienung einsetzen, die sich bequem über HTTP-Requests steuern lässt. Dazu ist lediglich die vom Arduino bekannte Bibliothek „IRremote“ in einer für den ESP8266 angepassten Form notwendig sowie eine IR-Diode mit passenden Widerstand bzw. ggf. noch ein Transistor zur Ansteuerung der LED.

Ein passender Sketch könnte wie folgt aussehen:

ir_server.ino
Arduino
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <ESP8266WebServer.h>
#include <ESP8266mDNS.h>
#include <IRremoteESP8266.h>
 
// WLAN data
const char* ssid = "xxx";
const char* password = "xxx";
 
// static IP
IPAddress ip(192,168,11,60);
IPAddress gateway(192,168,11,1);
IPAddress subnet(255,255,255,0);
 
MDNSResponder mdns;
ESP8266WebServer server(80);
 
// set your pin here
IRsend irsend(2);
 
void handleRoot() {
server.send(200, "text/html", "Please specify command! Form: /ir?code=xxx&bits=xx&protocol=x");
}
 
void handleIr(){
  String codestring=server.arg("code");
  String protocol=server.arg("protocol");
  String bitsstring=server.arg("bits");
 
  String webOutput = "Protocol: "+protocol+"; Code: "+codestring+"; Bits: "+bitsstring;
    
  if ((codestring != "")&&(bitsstring != "")){
    unsigned long code = codestring.toInt();
    int bits = bitsstring.toInt();
    
    if (protocol == "NEC"){
      server.send(200, "text/html", webOutput);
      irsend.sendNEC(code, bits);
    }
    else if (protocol == "Sony"){
      server.send(200, "text/html", webOutput);
      irsend.sendSony(code, bits);
    }
    else if (protocol == "Whynter"){
      server.send(200, "text/html", webOutput);
      irsend.sendWhynter(code, bits);
    }
    else if (protocol == "LG"){
      server.send(200, "text/html", webOutput);
      irsend.sendLG(code, bits);
    }
    else if (protocol == "RC5"){
      server.send(200, "text/html", webOutput);
      irsend.sendRC5(code, bits);
    }
    else if (protocol == "RC6"){
      server.send(200, "text/html", webOutput);
      irsend.sendRC6(code, bits);
    }
    else if (protocol == "DISH"){
      server.send(200, "text/html", webOutput);
      irsend.sendDISH(code, bits);
    }
    else if (protocol == "SharpRaw"){
      server.send(200, "text/html", webOutput);
      irsend.sendSharpRaw(code, bits);
    }
    else if (protocol == "Samsung"){
      server.send(200, "text/html", webOutput);
      irsend.sendSAMSUNG(code, bits);
    }
    else {
      server.send(200, "text/html", "Protocol not implemented!");
    }
  }
  else {
    server.send(200, "text/html", "Missing code or bits!");
  }
}
 
void handleNotFound(){
  server.send(404, "text/plain", "404");
}
void setup(void){
  irsend.begin();
  Serial.begin(9600);
  WiFi.begin(ssid, password);
  WiFi.config(ip, gateway, subnet);
  Serial.println("");
  // Wait for connection
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("Connected to ");
  Serial.println(ssid);
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
  
  if (mdns.begin("esp8266", WiFi.localIP())) {
    Serial.println("MDNS responder started");
  }
  
  server.on("/", handleRoot);
  server.on("/ir", handleIr);
  server.onNotFound(handleNotFound);
  
  server.begin();
  Serial.println("HTTP server started");
}
void loop(void){
  server.handleClient();
}

Gesteuert werden kann der ESP8266 nun einfach über HTTP-Requests an URL der Form

[IP]/ir?code=xxx&bits=xx&protocol=x

Die Codes, Bits und das Protokoll lässt sich von eigenen Fernbedienungen ebenfalls mit der Bibliothek und einem passenden Empfänger auslesen.

Verwendet werden kann das Ganze dann z.B. über Smartphone/Tablet-Apps wie NetIO oder auch zur Sprachsteuerung via AIVC.

Verwandte Artikel: